; PixelLauncher — Inno Setup 6 script
; Сборка:  python make_installer.py   (или: ISCC.exe installer.iss)
; Результат: PixelLauncherSetup2.1.0.exe в папке проекта.
; AppId должен оставаться неизменным, иначе обновление появится
; как отдельная программа.

#define MyAppName "PixelLauncher"
#define MyAppVersion "2.1.0"
#define MyAppPublisher "SuperBoys"
#define MyAppURL "https://pixellauncher.ru"
#define StageDir "build\stage"
#define MyIcon "build\launcher.ico"

[Setup]
AppId={{7B3F2A19-5C4E-4D8B-9F61-2E8A0C4D1B55}
AppName={#MyAppName}
AppVersion={#MyAppVersion}
AppVerName={#MyAppName} {#MyAppVersion}
AppPublisher={#MyAppPublisher}
AppPublisherURL={#MyAppURL}
DefaultDirName={localappdata}\{#MyAppName}
DisableProgramGroupPage=yes
; без UAC: лаунчер и .minecraft живут в профиле пользователя
PrivilegesRequired=lowest
OutputDir=.
OutputBaseFilename=PixelLauncherSetup{#MyAppVersion}
Compression=lzma2/max
SolidCompression=yes
WizardStyle=modern
MinVersion=10.0
ArchitecturesAllowed=x64compatible
SetupIconFile={#MyIcon}
UninstallDisplayIcon={app}\launcher.ico
UninstallDisplayName={#MyAppName}
VersionInfoVersion=2.1.0.0
VersionInfoProductVersion={#MyAppVersion}
LZMANumBlockThreads=2

[Languages]
Name: "russian"; MessagesFile: "compiler:Languages\Russian.isl"
Name: "english"; MessagesFile: "compiler:Default.isl"

[Tasks]
Name: "desktopicon"; Description: "Создать ярлык на рабочем столе"; \
    GroupDescription: "Дополнительно:"

[Files]
Source: "{#StageDir}\*"; DestDir: "{app}"; \
    Flags: recursesubdirs ignoreversion

[Icons]
; WorkingDir обязателен: настройки и .minecraft ищутся относительно папки
Name: "{autoprograms}\{#MyAppName}"; Filename: "{app}\pythonw.exe"; \
    Parameters: "main.py"; WorkingDir: "{app}"; \
    IconFilename: "{app}\launcher.ico"; Comment: "Оффлайн-лаунчер Minecraft"
Name: "{userdesktop}\{#MyAppName}"; Filename: "{app}\pythonw.exe"; \
    Parameters: "main.py"; WorkingDir: "{app}"; \
    IconFilename: "{app}\launcher.ico"; Tasks: desktopicon

[Registry]
; Протокол pixellauncher:// — ссылки с сайта открывает лаунчер
Root: HKCU; Subkey: "Software\Classes\pixellauncher"; \
    ValueType: string; ValueData: "URL:PixelLauncher Protocol"; \
    Flags: uninsdeletekey
Root: HKCU; Subkey: "Software\Classes\pixellauncher"; \
    ValueType: string; ValueName: "URL Protocol"; ValueData: ""
Root: HKCU; Subkey: "Software\Classes\pixellauncher\shell\open\command"; \
    ValueType: string; \
    ValueData: """{app}\pythonw.exe"" ""main.py"" ""--protocol-url"" ""%1"""

[Run]
Filename: "{app}\pythonw.exe"; Parameters: "main.py"; \
    WorkingDir: "{app}"; Description: "Запустить {#MyAppName}"; \
    Flags: nowait postinstall skipifsilent